defaults.fst
4.03 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% File: defaults.fst
% Author: Helmut Schmid; IMS, University of Stuttgart
% Date: July 2003
% Content: generation of default base, derivation and composition stems
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
$TMP$ = $VPrefStems$ $BaseStems$ || $NoDef2NULL$ || $PREFFILTER$
$TMP$ = ($BaseStems$ | $TMP$) || $KOMPOSFILTER$
$ANY$ = [\!-\~¡-ÿ <FB><SS><n><~n><e><d><Ge-Nom><UL> <NoHy><NoDef><ge><no-ge><CB>\
<Base_Stems><Deriv_Stems><Kompos_Stems><Pref_Stems><Suff_Stems>]*
$TMP$ = $TMP$ $FLEXION$
$TMP$ = $TMP$ || $ANY$ $FLEXFILTER$
$TMP$ = $TMP$ || $INFIXFILTER$
$TMP$ = $TMP$ || $UPLOW$
$TMP$ = <>:<WB> $TMP$ <>:<WB> || $PHON$
% default noun composition stems
$DefKomposNN$ = \
([\!-\~¡-ÿ]+ \
({<>}:{<+NN>[<Masc><Neut><Fem><NoGend>]<Nom><Sg>} |\
{<>}:{<+NN>[<Masc><Neut>] <Gen><Sg>} |\
% {<>}:{<^ADJ><Pos><+NN><NoGend><Nom><Pl><Sw/Mix>} |\
{<>}:{<+NN>[<Masc><Neut><Fem><NoGend>] <Nom><Pl>} <>:<Sw/Mix>?) || $TMP$) \
<NN>
$T$ = [Aa]rbeit|[hk]eit|[Ff]ahrt|[Gg]ang|kunft|[Nn]acht|ion|[Pp]flicht|\
schaft|[Ss]chrift|[Ss]icht|[Ss]ucht|tät|ung
$T$ = [\!-\~¡-ÿ]* $T$ {<>}:{<+NN>[<Fem><Masc>]<Nom><Sg>}
$T$ = $T$ || $TMP$
$DefKomposNN$ = $DefKomposNN$ |\
($T$ <NN> || [\!-\~¡-ÿ]* <>:s <NN>)
% default noun derivation stems
% delete final e and en in derivation stems unless a vowel precedes
$c$ = [bcdfghj-np-tvwxzß]
$C$ = [BCDFGHJ-NP-TVWXZbcdfghj-np-tvwxzß]
ALPHABET = [\!-\~¡-ÿ] <NN> [en]:<>
$Del-e$ = ($C$ e <=> <> ((n:.)? <NN>)) &\
(e:. n <=> <> <NN>)
% allow Umlautung in verbal and nominal derivation stems
ALPHABET = [\!-\~¡-ÿ<e>] [Aa]:[Ää] a:<> [<NN><V>]
$R1$ = ( A => Ä (u $c$* (e[rl])? [<NN><V>])) &\
($C$ a => ä ([au]:. $c$* (e[rl])? [<NN><V>])) &\
(a:ä a <=> <> ($c$* (e[rl])? [<NN><V>]))
ALPHABET = [\!-\~¡-ÿ<e>] [AOUaou]:[ÄÖÜäöü] [<NN><V>]
$R2$ = ( [AOU] => [ÄÖÜ] ($c$* (e[rl])? [<NN><V>])) &\
($C$ [aou] => [äöü] ($c$* (e[rl])? [<NN><V>]))
$Uml$ = $R1$ || $R2$
$DefDerivNN$ = (\
([\!-\~¡-ÿ]* \
<>:<+NN> <>:[<Masc><Fem><Neut><NoGend>] <>:<Nom> <>:<Sg> || $TMP$) \
<NN>) || $Del-e$ || $Uml$
% default proper name derivation stems
$DefDerivNE$ = \
([\!-\~¡-ÿ]* <>:<+NE> <>:[<Masc><Neut><Fem><NoGend>] <>:<Nom> <>:<Sg> || $TMP$) \
<NE>
% default proper name composition stems
$DefKomposNE$ = $DefDerivNE$
% default adjective base stems
$DefBaseADJ$ = \
(([\!-\~¡-ÿ<PREF>]* <V>:<+V><zu>?<PPast> ||\
$TMP$ || $NoDef2NULL$ t) <>:<ADJ><SUFF>:<><>:<base><>:<nativ><>:<Adj+e>) |\
(([\!-\~¡-ÿ<PREF>]* <V>:<+V><zu>?[<PPres><PPast>] ||\
$TMP$ || $NoDef2NULL$ (en|nd)) <>:<ADJ><SUFF>:<><>:<base><>:<nativ><>:<Adj+>)
% default adjective composition and derivation stems
$DefKomposADJ$ = (\
([\!-\~¡-ÿ]* <>:<+ADJ> <>:[<Pos><Comp><Sup>] <>:<Pred> |\
[\!-\~¡-ÿ<PREF>]* <V>:<+V><zu>?[<PPres><PPast>]) ||\
$TMP$ || $NoDef2NULL$) <ADJ>
$DefDerivADJ$ = $DefKomposADJ$
% default verb composition stems
$DefKomposV$ = ([\!-\~¡-ÿ<PREF>]* {<>}:{<+V><Inf>} || $TMP$) <V> ||\
[\!-\~¡-ÿ]* ({en}:{<>} | e[rl]n:<>) <V>
% default verb derivation stems
$DefDerivV$ = ([\!-\~¡-ÿ<PREF>]* {<>}:{<+V><Inf>} || $TMP$) <V> ||\
<NoDef>:<>? [\!-\~¡-ÿ]* ({en}:{<>} | e:<e> [rl] n:<>) <V> || $Uml$
ALPHABET = [\!-\~¡-ÿ] <NoDef> <e> <V> n:<en>
$R$ = ([bdgptkfs] | ch) n <=> <en> (<V>)
ALPHABET = [\!-\~¡-ÿ] <NoDef> <e> <V>
$R$ = $R$ || (. | <>:<e><en>:n)*
$DefDerivV$ = $DefDerivV$ || $R$
$BDKStems$ = ($BDKStems$ || $NoDef2NULL$) | <>:<Base_Stems> $DefBaseADJ$ |\
(<>:<Deriv_Stems> ($DefDerivADJ$ | $DefDerivNN$ | $DefDerivNE$ | $DefDerivV$)\
<>:<deriv> |\
<>:<Kompos_Stems> ($DefKomposADJ$ | $DefKomposNE$ |\
$DefKomposNN$ | $DefKomposV$) <>:<kompos>)\
<>:<nativ>
% default stems for generating "Gejammer", "Gejammere", "Gejammre"
$T$ = $BDKStems$ || (\
<NoDef>:<>? <ge> <Base_Stems>:<Deriv_Stems> [\!-\~¡-ÿ<e>]+ \
(<>:e<V><base>:<deriv><nativ> [<VVReg><VVPres><VVPres1><VVPres1+Imp>]:<>|\
({<e>l}:{le}|{<e>r}:{re}|<>:e)? \
<V><base>:<deriv><nativ><VVReg-el/er>:<>))
$BDKStems$ = $BDKStems$ | $T$