phon.fst
1.72 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
%**************************************************************************
% File: phon.fst
% Author: Helmut Schmid; IMS, University of Stuttgart
% Content: morphophonological rules
% Modified: Mon Nov 6 09:23:31 2006 (schmid)
%**************************************************************************
#include "symbols.fst"
%%% adjective rules %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% easy+er -> easier
% easy+est -> easiest
% late+er -> later
% red -> redder
ALPHABET = [#Letter# #EntryType# #WordClass# #Cap#] \
y:i e:<> <ADJ>:<dup>
$C$ = [<ADJ><ADV>]
$T$ = ([hwxaioue] $C$) e <=> <> (r | st) &\
[#Cons#] y <=> i ($C$ e(r|st)) &\
([#Cons#][#vowel#][#cons#]) <ADJ> <=> <dup> (e(r|st))
ALPHABET = [#Letter# #EntryType# #WordClass# #Cap#]
#=1# = #cons#
$X$ = [#=1#] <>:<ADJ> <dup>:[#=1#]
$Rule1$ = $T$ || (.* $X$)* .*
%%% noun rules %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% story -> stories
% wish -> wishes (also verbs)
ALPHABET = [#Letter# #EntryType# #WordClass# #Cap#]
$T$ = {y}:{ie} ^-> ([#cons#] __ [<N><V>] s)
$Rule2$ = $T$ || <>:e ^-> (([szx]|[cs]h) __ [<N><V>] s)
%%% verb rules %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% delete -> deleting
ALPHABET = [#Letter# #EntryType# #WordClass# #Cap#] e:<> y:i
$Rule3$ = e <=> <> (<V> (ing|ed)) &\
[#cons#] y <=> i (<V> ed)
%%% capitalisation %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
ALPHABET = [#Letter#] [#WordClass#]:<>
$T$ = .* \
([#EntryType#]:<> ([#LETTER#]:[#letter#] | [#letter#]) .*)* \
[#Cap#]
$Capitalisation$ = $T$ || (\
([#LETTER#]:[#letter#] | [#letter#]) .* <LC>:<> |\
([#letter#]:[#LETTER#] | [#LETTER#]) .* <UC>:<> |\
.* <FC>:<>)
$Rule1$ || $Rule2$ || $Rule3$ || $Capitalisation$